Cerradura LCD + Teclado 3x4 con 16f628a

Bueno aquí les dejo un video de una cerradura electrónica hecha con el pic 16f628a. Más tarde pondre el esquema y el codigo en pbp



Este es el esquema en Proteus:



En vez de poner un relé he puesto un led pero a efectos es lo mismo poniendo un transistor podremos controlar cargas mayores.

Despues de una pequeña revisión, me he dado cuenta que si se pone RS en el A4 no funciona la simulación, pero solo en la simulación. de todas maneras he cambiado la foto del esquema y el código. Aunque el problema estaba solo ahí. También os dejo los archivos en Proteus y los de PBP en la sección de descargas

Y este es el codigo en PBP:

;Cerradura Electronica Electronica con teclado 3x4,Lcd 16x2,
;y clave de 4 digitos que queda grabada aun cuando el Pic
;deje de tener corriente.
;utiza el micro 16f628a prescidiendo del cristal de cuarzo
;externo y usando el reloj interno
@ DEVICE PIC16F628A, WDT_OFF
@ DEVICE PIC16F628A, PWRT_ON
@ DEVICE PIC16F628A, BOD_ON
@ DEVICE PIC16F628A, PROTECT_OFF
@ DEVICE PIC16F628A, CPD_OFF
@ DEVICE PIC16F628A, MCLR_OFF
@ DEVICE PIC16F628A, INTRC_OSC_NOCLKOUT
@ DEVICE PIC16F628A, LVP_OFF

DEFINE LCD_DREG PORTA ;port de Data LCD
DEFINE LCD_DBIT 0 ;datos LCD comenzando en BIT 0 o 4 "estos deven estar consecutivos"
DEFINE LCD_EREG PORTB ;cambiamos Enable del portb.3
DEFINE LCD_EBIT 7 ;al portb.7
DEFINE LCD_RSREG PORTA
DEFINE LCD_RSBIT 7

;definicion de variables
a var word
tecla var word
n1 var byte
n2 var byte
n3 var byte
n4 var byte
eprom1 var byte
;definiendo puertos
LA var portb.0 ;Linea A
LB var portb.1 ;Linea B
LC var portb.2 ;Linea C
LD var portb.3 ;Linea D
Funo var portb.4 ;Columna 1
Fdos var portb.5 ;Columna 2
Ftres var portb.6 ;Columna 3
rele var porta.6 ;Rele

n1="1" ;asigno valor a las variables
n2="1" ;el valor es equivalente en asccII
n3="1" ;esta sera la combinación predefinida
n4="1" ;recuerda cambiarla!!


eprom1="0"

PAUSE 100 ; Inicio del programa
read 0,eprom1
if eprom1 = 255 then gravar_clave
goto bienvenida

gravar_clave:
WRITe 0, n1
WRITe 1, n2
WRITe 2, n3
WRITe 3, n4

LCDOUT $FE,1, $FE,2, " CLAVE GRABADA "
PAUSE 1500
GOTO bienvenida

Bienvenida:
pause 500 ; Mensaje de Bienvenida
LCDOUT $FE,1, $FE,2, " Infotronikblog "
LCDOUT $FE,$C0," Presenta: "

inicio:
pause 500
LOW LA
LOW LB
HIGH LC
LOW lD ;Activamos la linea del asterisco
IF fUNO = 0 then goto clave
pause 500 ;LEE EL TECLADO A VER SI ES "*"
; SI NO ES CONTINUA MOSTRANDO MENSAJE
goto inicio


teclado: ;Etiqueta para el teclado


low la
if funo = 0 then uno
if fdos = 0 then dos
if ftres = 0 then tres

high la
low lb
if funo = 0 then cuatro
if fdos = 0 then cinco
if ftres = 0 then seis


high lb
low lc
if funo = 0 then siete
if fdos = 0 then ocho
if ftres = 0 then nueve

high lc
low ld
if funo = 0 then asterisco
if fdos = 0 then cero
if ftres = 0 then numeral
high ld
pause 10
goto teclado

asterisco:
tecla="*"
return

siete:
tecla="7"
return

cuatro:
tecla="4"
return

uno:
tecla="1"
return

dos:
tecla="2"
return

cinco:
tecla="5"
return

ocho:
tecla="8"
return

cero:
tecla="0"
return

tres:
tecla="3"
return

seis:
tecla="6"
return

nueve:
tecla="9"
return

numeral:
tecla="#"
return

clave:
LCDOUT $FE,1, $FE,2, "Escribe la Clave"
pause 1000
gosub teclado
SWAP tecla, n1
LCDOUT $FE,$C5, "*"
pause 500
gosub teclado
SWAP tecla, n2
LCDOUT $FE,$C6, "*"
pause 500
gosub teclado
SWAP tecla, n3
LCDOUT $FE,$C7, "*"
pause 500
gosub teclado
SWAP tecla, n4
LCDOUT $FE,$C8, "*"
pause 500

READ 0,EPROM1
IF eprom1 = n1 then miro_dos

Error:
LCDOUT $FE,1, $FE,2, "Clave Incorrecta"
pause 500
goto bienvenida

miro_dos:
READ 1, eprom1
IF eprom1 = n2 then miro_tres
goto error

miro_tres:
READ 2, eprom1
IF eprom1 = n3 then miro_cuatro
goto error

miro_cuatro:
READ 3, eprom1
IF eprom1 = n4 then goto menu
goto error



menu:
LCDOUT $FE,1, " Elige una "
LCDOUT $FE,$C0," Opcion: "

pause 1500
LCDOUT $FE,1,"1 Abrir Puerta"
pause 300
LCDOUT $FE,$C0,"2 Cambiar Clave"
gosub teclado
IF tecla = "1" THEN goto abrir
if tecla = "2" then goto nueva_clave
if tecla != "1" and tecla!= "2" then LCDOUT $FE,1, $FE,2, "TECLA INCORRECTA" ;Si pulsamos una
LCDOUT $FE,1, $FE,2, "TECLA INCORRECTA " ;que no es ni 1 ni 2 muestra tecla incorrecta
pause 700
goto menu

abrir:
high rele
LCDOUT $FE,1, $FE,2, " Bienvenido "
pause 3000
low rele
goto bienvenida

nueva_clave:
LCDOUT $FE,1, $FE,2, "Escribe tu nueva"
LCDOUT $FE,$C0,"Clave:"
pause 500
gosub teclado
SWAP tecla, n1
LCDOUT $FE,$C8,"*"
pause 500
gosub teclado
SWAP tecla, n2
LCDOUT $FE,$C9,"*"
pause 500
gosub teclado
SWAP tecla, n3
LCDOUT $FE,$C9+1,"*"
pause 500
gosub teclado
SWAP tecla, n4
LCDOUT $FE,$C9+2,"*"
pause 500
goto gravar_clave


;---------------------------------FIN DEL CODIGO----------------------------------

Descargar archivos: Cerradura LCD con Teclado 3x4 para 16f628a






*NOTA: En la simulación la clave esta cambiada a 2580 *